F1key無効化バッチ
社用PCで作業中、F1キーを誤って押下してヘルプが出てしまい萎える事がよくあります。
私は正直Windowsヘルプを全然使用しないため、ヘルプが出てくることによって作業効率が落ちない様にF1キー無効化の方法を探しました。
せっかく調査したので備忘までに記事をおこしておきます。
上記の記事を参考にさせていただきました。
ただし、ここまでは手動実行のようだったので自動化をとりいれてみました。
（キーマップが同じ人だけ自己責任で実施してください。）
＝ここから＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
@echo off
REM ======================================
REM F1key無効化処理バッチ
REM 作成者 赤塚
REM 作成日 2017/11/30
REM ======================================
REM カレントディレクトリへ移動
cd %~dp0
set TODAY=%date:~0,4%%date:~5,2%%date:~8,2%
set log=.\%~n_%TODAY%.log
REM 実行確認
echo 実行日は%TODAY%です。
echo 実行日は%TODAY%です。> %log%
set /P answer="F1keyを無効化しますか？（Y/N）： "
IF "%answer%" == "y" (
GOTO START
) ELSE IF "%answer%"=="Y" (
GOTO START
) ELSE (
GOTO END
)
:START
set key="HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Keyboard Layout"
set value="Scancode Map"
echo 処理を開始します
echo 処理を開始します >> %log%
reg add %key% /v %value% /t REG_BINARY /d "00 00 00 00 00 00 00 00 02 00 00 00 00 00 3B 00 00 00 00 00" >> %log% 2>&1
reg query %key% /v %value% >> %log%
echo F1keyの無効化処理を実施しました。
echo F1keyの無効化処理を実施しました。 >> %log%
echo 動作確認（F1key無効化確認）を実施してください。
echo 動作確認（F1key無効化確認）を実施してください。 >> %log%
pause
notepad %log%
exit /b
:END
echo F1keyの無効化をキャンセルしました。
echo F1keyの無効化をキャンセルしました。 >> %log%
pause
notepad %log%
exit /b
＝ここまで＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
ご使用の際の手順
①上記のテキストをメモ帳に貼り付ける。
②拡張子を「.bat」にして保存する。
③Admin権限のユーザでログインしダブルクリックで実行
注意：F1キーを押しても何も反応しなくなります（そのための設定ですがｗ)
怖くなったら以下のキーを削除すれば動作が元にもどります。
\HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Keyboard Layout\Scancode Map
以上です。
